生成元=(γ^8)+(γ^4)+(γ^3)+(γ^2)+1;
加法表示[x_]:=PolynomialMod[x,{生成元,2}]
F256=Prepend[Table[加法表示[(γ^k)],{k,0,254}],0];
位置[L_,e_]:=Position[L,e][[1]][[1]];
乗法表示[x_]:=If[x===0,0,γ^(位置[F256,加法表示[x]]-2)];
生成多項式[n_,k_] :=Collect[Product[x+γ^i,{i,0,n-k-1}],x,乗法表示];

漢字Mode={{1,0,0,0}};
文字数[data_,"漢字"]:={IntegerDigits[
StringLength[data],2,8]};
ずらし[code_]:=If[code[[1]]≤224,code-{129,64},code-{193,64}];
漢字Data[data_]:=Map[IntegerDigits[#,2,13]&,
Map[#[[1]]*192+#[[2]]&,
Map[ずらし,Partition[ToCharacterCode[data,"ShiftJIS"],2]]]];
終端Pattern={{0,0,0,0}};
漢字情報語[data_]:=Partition[
Partition[Flatten[
Join[漢字Mode,文字数[data,"漢字"],漢字Data[data],終端Pattern]],
8,8,1,0],
9,9,1,{{1,1,1,0,1,1,0,0},
{0,0,0,1,0,0,0,1}}][[1]];

情報多項式[word_]:=Map[加法表示[#.Table[(γ^((7-i))),{i,0,7}]]&,word
].Table[x^(9-i),{i,1,9}];
符号多項式[poly_]:=
Collect[PolynomialMod[
poly*x^17+PolynomialRemainder[poly*x^17,生成多項式[26,9],x],
{生成元,2}],x];
符号語[poly_]:=Mod[Map[Table[Coefficient[加法表示[#],γ,7-i],{i,0,7}] &,Table[Coefficient[poly,x,25-i],
{i,0,25}]],2];

氏名="大谷翔平";

漢字情報語[氏名]

漢字情報語[氏名]//TableForm

情報多項式[漢字情報語[氏名]]//TraditionalForm

符号多項式[情報多項式[漢字情報語[氏名]]]//TraditionalForm

符号語[符号多項式[情報多項式[漢字情報語[氏名]]]]

ExportString[Table[符号語[符号多項式[情報多項式[漢字情報語[氏名]]]][[i]],{i,1,26}],"TSV"]