学籍番号をＱＲコードにしてみる。

学籍番号="15B4144010D"

生成元=1+(γ^2)+(γ^3)+(γ^4)+(γ^8);
加法表示[x_]:=PolynomialMod[x,{生成元,2}]
F256=Prepend[Table[加法表示[(γ^k)],{k,0,254}],0];
位置[L_,e_]:=Position[L,e][[1]][[1]];
乗法表示[x_]:=γ^(位置[F256,加法表示[x]]-2);
英数字[x_]:=
Which[DigitQ[x],ToCharacterCode[x][[1]]-48,
LetterQ[x],ToCharacterCode[ToUpperCase[x]][[1]]-55,
True,Switch[x," ",36,"$",37,"%",38,"*",39,
"+",40,"-",41,".",42,"/",43,":",44,_,"エラー：英数字モードでは扱えません"]];
生成多項式 =Collect[Product[x+γ^i,{i,0,12}],x,乗法表示];
符号化[vector_]:=
Collect[
PolynomialMod[
vector.Table[x^(Length[vector]+13-i),{i,1,Length[vector]}]+
PolynomialMod[vector.Table[x^(Length[vector]+13-i),{i,1,Length[vector]}],{生成多項式,2}],2],
x,乗法表示];
復号[polynomial_]:=
Map[乗法表示,Table[Coefficient[polynomial,x,25-i],{i,0,12}]];

DATA0={{0,0,1,0}}

DATA1=Append[DATA0,IntegerDigits[
StringLength[学籍番号]+2^9,2][[2;;10]]]

DATA2=Join[DATA1,Map[If[Length[#]==2,
IntegerDigits[#.{45,1}+2^11,2][[2;;12]],
IntegerDigits[#[[1]]+2^6,2][[2;;7]]]&,
Partition[Map[英数字,Characters[学籍番号]],2,2,1,{}]]]

DATA3=Append[DATA2,{0,0,0,0}]

DATA4=Partition[Flatten[DATA3],8,8,1,0]

DATA=Partition[DATA4
,13,13,1,
{{1,1,1,0,1,1,0,0},
{0,0,0,1,0,0,0,1}}][[1]]

符号多項式=符号化[Map[乗法表示[#.Table[(γ^((7-i))),{i,0,7}]]&,DATA]]

符号語0=Table[Coefficient[符号多項式,x,25-i],
{i,0,25}]

符号語=Mod[Map[Table[Coefficient[加法表示[#],γ,7-i],{i,0,7}] &,符号語0],2]

ExportString[符号語,"Table"]