学籍番号をＱＲコードにしてみる。

学籍番号="14B1104019B"

必要な関数の定義がこの下に隠れています。

英数字MODE[x_]:=
Which[DigitQ[x],ToCharacterCode[x][[1]]-48,
LetterQ[x],ToCharacterCode[ToUpperCase[x]][[1]]-55,
True,Switch[x," ",36,"$",37,"%",38,"*",39,
"+",40,"-",41,".",42,"/",43,":",44,_,"エラー：英数字MODEでは扱えません"]];
minimal = (γ^8)+(γ^4)+(γ^3)+(γ^2)+1;
additive=Table[
PolynomialMod[γ^(254-i),{minimal ,2}],
{i,0,254}]~
Join~{0};
multiplicative=Table[γ^(254-i),{i,0,254}]~
Join~{0};
toA[elem_]:=PolynomialMod[elem,{minimal ,2}];
For[i= 1, i<256,i++,toM0[additive[[i]]]=γ^(255-i)];
toM0[0]=0;
toM[elem_]:=toM0[PolynomialMod[elem,{minimal ,2}]];
generator =Collect[Product[x+γ^i,{i,0,12}],x,toM];
encode[vector_]:=
Collect[
PolynomialMod[
vector.Table[x^(Length[vector]+13-i),{i,1,Length[vector]}]+
PolynomialMod[vector.Table[x^(Length[vector]+13-i),{i,1,Length[vector]}],{generator,2}],2],
x,toM];
decode[polynomial_]:=
Map[toM,Table[Coefficient[polynomial,x,25-i],{i,0,12}]];

DETA={{0,0,1,0}};
DETA=Append[DETA,IntegerDigits[
StringLength[学籍番号]+2^9,2][[2;;10]]];
DETA=Join[DETA,Map[If[Length[#]==2,
IntegerDigits[#.{45,1}+2^11,2][[2;;12]],
IntegerDigits[#[[1]]+2^6,2][[2;;7]]]&,
Partition[Map[英数字MODE,Characters[学籍番号]],2,2,1,{}]]];
DETA=Append[DETA,{0,0,0,0}];
DETA=Partition[Flatten[DETA],8,8,1,0];
DETA=Partition[DETA,13,13,1,
{{1,1,1,0,1,1,0,0},
{0,0,0,1,0,0,0,1}}][[1]]

符号多項式=encode[Map[toM[#.Table[(γ^((7-i))),{i,0,7}]]&,DETA]]

符号語２=Table[Coefficient[符号多項式,x,25-i],
{i,0,25}]

符号語=Mod[Map[Table[Coefficient[toA[#],γ,7-i],{i,0,7}] &,符号語２],2]

ExportString[符号語,"Table"]